Hatena::ブログ(Diary)

SHIROのモバイル日記 RSSフィード Twitter

2017-01-08

[]LED人形

FacebookIchigoJam-FANグループで、LEDと抵抗をハンダ付けして人形を作った人がいたので、私も作ってみました。
f:id:shiro0922:20170108100455j:image:w360
LEDに100Ωの抵抗を2本ハンダ付けするだけ。子どもでも作れるように、簡単な作りにしました。
テーブルにセロテープで留めると、ハンダ付けがやりやすいです。本当はテーブルが焦げないように板を敷くといいですが。
f:id:shiro0922:20170108102500j:image:w360

IchigoJamに2体の人形の足を差して、プログラムでランダムに光らせてみました。
2人でお話しているように見えて、なかなか面白いです。
f:id:shiro0922:20170108103124j:image:w360

プログラムはこちら。
人形1の足をGNDとOUT1、人形2の足をGNDとOUT5に差しています。

10 VIDEO 0,10:OUT 0
20 OUT RND(2)+RND(2)*16
30 WAIT 1+RND(5),0
40 GOTO 20
情報センターのIchigoJam展示にも追加しました。
f:id:shiro0922:20170108111036j:image:w360

2016-12-23

[]3156キットで「さいころサイモン」

※「IchigoJam Advent Calendar 2016」にエントリーしました。

PCNで「3156(さいころ)組み立てキット」が新発売。LEDでさいころの目を光らせるシールド基板です。
さっそく購入して組み立ててみました。
f:id:shiro0922:20161221170451j:image:w360

f:id:shiro0922:20161221170649j:image:w360

f:id:shiro0922:20161221170649j:image:w360

f:id:shiro0922:20161221174654j:image:w360

f:id:shiro0922:20161221174948j:image:w360

f:id:shiro0922:20161224155425p:image:w360
ハンダ付けは30分ほどで完成。音も鳴らしたかったので、圧電ブザーを無理矢理付けました。
作って気付いた点としては、チルトスイッチの「45度の角度に曲げてハンダ付け」が案外難しいです。リードを真っ直ぐなまま浮かせてハンダ付けして、後で曲げた方がやりやすいと思います。

さて、ただの「振ると目が出るさいころ」では面白くないので、「さいころサイモン」を作ってみました。
D

  • IchigoJamに3156基板(+圧電ブザー)を装着します。
  • プログラムを起動すると「ピピッ」と起動音の後、1〜6の目のどれかが1個出題されます。
  • 出題された目を入力します。基板を上下に振ると「1→2→3→4→5→6→1→…」と目が変わるので、希望の目になった所でIchigoJamのボタンを押します。正しい入力をするとその音階が鳴り、IchigoJamのLEDが点滅します。
  • 問題に正解すると「ピピッ」と音が鳴り、次は出題数が1個増えます。同様に入力してください。
  • 間違った目を入力すると、「プー」とエラー音が出てゲームオーバーになります。IchigoJamのLEDが点きっぱなしになります。
  • 出題数90個まで正解すると、1個の出題に戻ります。(まずそこまで行けないでしょう)

1〜6のそれぞれの目で、ド〜ラの音階が鳴ります。
圧電ブザー無しでもプレイできますが、音があった方が断然楽しいです。

MixJuiceでもダウンロードできます。
? "MJ GET comich.net/ichigojam/3156simon.txt"

10 '*3156 Simon
20 CLV:VIDEO 0:SRND(ANA(2))
30 P="C;D;E;F;G;A;"
40 LET [91],1,2,3,6,7,14
50 WAIT 60
60 '@GAMELOOP
70 OUT 0:GSB 180:WAIT 60
80 L=L+1:IF L>90 L=1
90 [L]=RND(6)+1
100 FOR I=1 TO L:D=[I]:GSB 200:NEXT
110 OUT 0:WAIT 60:GSB 180
120 I=0:D=1:GSB 230
130 '@INLOOP
140 I=I+1:GSB 250
150 IF D<>[I] BEEP 30,90:LED 1:END
160 GSB 200:IF I<L GOTO 130
170 WAIT 30:GOTO 60
180 '@PP
190 BEEP 8:WAIT 8:BEEP 8:RTN
200 '@PLAY1
210 GSB 230
220 PLAY P+(D-1)*2:LED 1:WAIT 30:LED 0:RTN
230 '@PRTD
240 OUT [90+D]:RTN
250 '@IN1
260 IF BTN() RTN
270 IF IN(1) GOTO 250
280 D=D+1:IF D>6 D=1
290 BEEP:GSB 230:WAIT 20:GOTO 250

2016-12-03

[]大砲ゲーム

IchigoJam Advent Calendar 2016」エントリー用に、簡単なプログラムを作ってみました。
放映中の大河ドラマ真田丸」にヒントを得た「大砲ゲーム」です。
f:id:shiro0922:20161201212959p:image:w360

f:id:shiro0922:20161201213030p:image:w360

  • 起動すると、画面下に大砲の弾、右下に大坂城が表示されます。ちなみに天守閣左側の「○」は、我らが真田丸です(^_^)
  • 弾の右側に、縦に移動する照準「+」が出ます。発射したい角度に来た所でスペースキーを押してください。
  • 弾が発射されて飛んでいきます。お城に当たるとスコアが1点加算されます。
  • 次は大砲が移動して、お城までの距離が変わります。再び狙ってください。
  • 弾を10発打つと戦いは終了です。あなたの徳川軍は、大坂城に何発当てられるでしょうか?

MixJuiceでもダウンロードできます。
? "MJ GET comich.net/ichigojam/taihou.txt"

10 CLV:FOR T=1 TO 10:CLS:?S
20 LC 27,21:?CHR$(159,143,158);
30 LC 28,22:?CHR$(143);
40 LC 26,23:?CHR$(232,159,143,158);
50 X=RND(20)+4:Y=23:LC X,Y:?CHR$(233);:V=0
60 V=(V+1)*(V<5):LC X+2,22-V:?"+":L=0
70 IF BTN(SPACE) GOTO 100
80 L=L+1:IF L<150 GOTO 70
90 LC X+2,22-V:?CHR$(0):GOTO 60
100 LC X+2,22-V:?CHR$(0):V=-V-1:BEEP
110 LC X,Y:?" ";
120 X=X+2:Y=Y+V:V=V+1:H=SCR(X,Y)
130 LC X,Y:?CHR$(233);:WAIT 10
140 IF Y<23 AND X<30 AND !H GOTO 110
150 IF H BEEP:LC X,Y:?"*";:S=S+1
160 LC 0,0:?S:WAIT 60:NEXT:END

2016-11-26

[]IchigoBell BIG

IchigoBellの機能強化版「IchigoBell BIG」を作ってみました。
f:id:shiro0922:20161126020904j:image:w360
サウンド出力に2SC1815一石アンプを付けて、スピーカー出力にしました。
スピーカーは100円ショップの小型スピーカーを分解して取り出し。
全体を大きめのお好み焼きコテに載せて、電池単3×3に強化しました。
スピーカーで出力すると、さすがに音が段違いに良いです。
回路図はこちら。
f:id:shiro0922:20161126155938p:image:w360
プログラムの方も、1曲しか入れないのはもったいないので、スロット0に曲セレクタープログラムを入れて、スロット1〜3の3曲を選べるようにしました。

曲セレクター

  • スイッチを入れて自動起動すると、「プー」と起動音が鳴ります。
  • 上下に1回振るとスロット1、2回振るとスロット2、3回振るとスロット3の曲を選択します。(マグマ大使方式 笑)
  • 4回以上振った場合はエラーになり、最初にもどります。

10 '*Music Selecter
20 CLV:VIDEO 0:WAIT 60
30 A=0:BEEP 30,60:WAIT 60
40 IF ANA(2)>530 GOTO 40
50 GOSUB 110
60 IF ANA(2)<530 GOSUB 110
70 IF TICK()<60 GOTO 60
80 IF A>3 GOTO 30
90 BEEP 10,5:WAIT 8:BEEP 10,5
100 LRUN A
110 A=A+1
120 LED 1:BEEP:WAIT 15:LED 0:WAIT 15
130 CLT:RETURN

2016-11-23

[]IchigoBell完成

これまで試作してきたIchigoJamハンドベル「IchigoBell」ですが、
(記事1)http://d.hatena.ne.jp/shiro0922/20161102
(記事2)http://d.hatena.ne.jp/shiro0922/20161122
12/17〜18に情報センターで開催するクリスマスイベント「St. Media Xmas 2016」用に、本製作しました。
f:id:shiro0922:20161123161638j:image:w360
コテを3本も揃えて、どこのお好み焼き屋だ?(笑)

  • お好み焼き用コテを、100円ショップで買ったプラスチック製に変更。プラスチックなので絶縁対策不要。
  • 裏面の電池も単4×3に変更して、全体を軽量化

内蔵メロディは「ジングルベル」「サンタが街にやってくる」「赤鼻のトナカイ」の3種類です。
リストは以下に載せます。
なお、IFでアナログ入力を判断している行を、

IF !BTN() GOTO 〜
に変えれば、通常のIchigoJamでもボタンを押して演奏できます。

ジングルベル(11/26修正)

10 '*Jingle Bell 2
20 LET[0],"C;","A;","G;","F;","C;","C;","C;","R;"
30 LET[8],"C;","A;","G;","F;","D;","D;","D;","R;"
40 LET[16],"D;","A#;","A;","G;","E;","E;","E;","R;"
50 LET[24],"<C;","<C;","A#;","G;","A;","A;","A;","R;"
60 LET[32],"D;","A#;","A;","G;","<C;","<C;","<C;","<C;"
70 LET[40],"<D;","<C;","A#;","G;","F;","R;","<C;","R;"
80 LET[48],"A;","A;","A;","R;","A;","A;","A;","R;"
90 LET[56],"A;","<C;","F;","F8G8;","A;","A;","A;","R;"
100 LET[64],"A#;","A#;","A#;","A#;","A#;","A;","A;","A;"
110 LET[72],"A;","G;","G;","F;","G;","R;","<C;","R;"
120 LET[80],"A#;","A#;","A#;","A#;","A#;","A;","A;","A;"
130 LET[88],"<C;","<C;","A#;","G;","F;","F;","F;","R;"
140 A=0:B=16:C=32:D=48:E=64:F=80:VIDEO0
150 FORX=ATOA+15:GSB240:NEXT
160 FORX=BTOB+15:GSB240:NEXT
170 FORX=ATOA+15:GSB240:NEXT
180 FORX=CTOC+15:GSB240:NEXT
190 FORX=DTOD+15:GSB240:NEXT
200 FORX=ETOE+15:GSB240:NEXT
210 FORX=DTOD+15:GSB240:NEXT
220 FORX=FTOF+15:GSB240:NEXT
230 GOTO150
240 IFANA(2)>530GOTO240
250 LED1:PLAY[X]:WAIT20:LED0:RTN

サンタが街にやってくる(11/26修正)

10 '*Santa ga Machi ni Yattekuru
20 LET [0],"E8F8;","G;","G;","R;","A8B8;","<C;","<C;","R;"
30 LET [8],"E8F8;","G;","G;","G;","A8G8;","F;","F;","R;"
40 LET [16],"E;","G;","C;","E;","D;","F;","R;",">B;"
50 LET [24],"C;","C;","C;","C;","C;","C;","C;","R;"
60 LET [32],"<C;","<D;","<C;","B;","<C;","A;","A;","R;"
70 LET [40],"<C;","<D;","<C;","B;","<C;","A;","A;","R;"
80 LET [48],"<D;","<E;","<D;","<C#;","<D;","B;","B;","R;"
90 LET [56],"B8<C8;","<D;","<C;","B;","A;","G;","G;","R;"
100 A=0:B=32:VIDEO 0
110 FOR X=A TO A+31
120 GOSUB 210
130 NEXT
140 FOR X=B TO B+31
150 GOSUB 210
160 NEXT
170 FOR X=A TO A+31
180 GOSUB 210
190 NEXT
200 GOTO 110
210 IF ANA(2)>530 GOTO 210
220 LED 1:PLAY [X]:WAIT 20:LED 0
230 RETURN

赤鼻のトナカイ(11/26修正)

10 '*Akahana no Tonakai
20 LET [0],"G;","A8G8;","E;","<C;","A;","G;","G;","R;"
30 LET [8],"G8A8;","G8A8;","G;","<C;","B;","B;","B;","R;"
40 LET [16],"F;","G8F8;","D;","B;","A;","G;","G;","R;"
50 LET [24],"G8A8;","G8A8;","G;","A;","E;","E;","E;","R;"
60 LET [32],"G8A8;","R8G8;","E;","<C;","A;","G;","G;","R;"
70 LET [40],"G8A8;","G8A8;","G;","<C;","B;","B;","B;","R;"
80 LET [48],"F8G8;","R8F8;","D;","B;","A;","G;","G;","R;"
90 LET [56],"G8A8;","G8A8;","G;","<D;","<C;","<C;","<C;","R;"
100 LET [64],"A;","A;","<C;","A;","G;","E;","G;","R;"
110 LET [72],"F;","A;","G;","F;","E;","E;","E;","R;"
120 LET [80],"D;","E;","G;","A;","B;","B;","B;","R;"
130 LET [88],"<C;","<C;","B;","A;","G;","F8D8;","D;","R;"
140 A=0:B=32:C=64:VIDEO 0
150 FOR X=A TO A+31
160 GOSUB 280
170 NEXT
180 FOR X=B TO B+31
190 GOSUB 280
200 NEXT
210 FOR X=C TO C+31
220 GOSUB 280
230 NEXT
240 FOR X=B TO B+31
250 GOSUB 280
260 NEXT
270 GOTO 150
280 IF ANA(2)>530 GOTO 280
290 LED 1:PLAY [X]:WAIT 20:LED 0
300 RETURN

もろびとこぞりて(11/25追加)

10 '*Morobito Kozorite
20 LET [0],"<C;","<C;","B;","B8A8","G;","G;","G8R8;","F;"
30 LET [8],"E;","E;","D;","D;","C;","C;","C8R8;","G;"
40 LET [16],"A;","A;","A8R8;","A;","B;","B;","B8R8;","B;"
50 LET [24],"<C;","<C;","<C;","<C;","<C;","<C;","R;","<C;"
60 LET [32],"<C;","B;","A;","G;","G;","G8F8;","E8R8;","<C;"
70 LET [40],"<C;","B;","A;","G;","G;","G8F8;","E8R8;","E;"
80 LET [48],"E;","E;","E;","E8F8;","G;","G;","G8R8;","F8E8;"
90 LET [56],"D;","D;","D;","D8E8;","F;","F;","F8R8;","E8D8;"
100 LET [64],"C;","<C;","<C;","A;","G;","G8F8;","E;","F;"
110 LET [72],"E;","E;","D;","D;","C;","C;","C;","R;"
120 L=79:VIDEO 0
130 FOR X=0 TO L
140 IF ANA(2)>530 GOTO 140
150 LED 1:PLAY [X]:WAIT 20:LED 0
160 NEXT
170 GOTO 130

→さらに機能強化した「IchigoBell BIG」はこちら。
http://d.hatena.ne.jp/shiro0922/20161126

ダウンロード
リンク集
アクセスカウンター