Hatena::ブログ(Diary)

SHIROのモバイル日記 RSSフィード Twitter

2015-07-16

[]7セグメントLED拡張基板

ソケットの配置が変わったIchigoJam Uに合わせて、さっそく簡単な拡張基板を作ってみました。
7セグメントLEDを光らせます。
f:id:shiro0922:20150715233729j:image:w360
以前作った「IchigoMax」と同様に2階建てです。

f:id:shiro0922:20150715233947j:image:w360
脚の長いソケットを使っています。
秋月電子から通販で買いました。
http://akizukidenshi.com/catalog/g/gC-07912/
http://akizukidenshi.com/catalog/g/gC-07913/

f:id:shiro0922:20150715235738j:image:w360

f:id:shiro0922:20150715235201j:image:w360
今回使った7セグメントLEDの内部回路図と、Excelで引いた基板配線図。
IchigoJamのOUT1〜6とLEDピンの出力が、7セグメントLEDのa〜gに対応します。

f:id:shiro0922:20150715155753j:image:w360
0〜9の数字を表示する、ルーレットプログラムを作ってみました。
ボタンを押すと、ルーレットが回って止まります。

10 '*7SEG ROULETTE*
20 LET [0],`0111111,`0000110,`1011011,`1001111,`1100110,`1101101,`1111101,`0100111,`1111111,`1101111
30 N=0
40 GOSUB 200
50 '@START
60 IF BTN()==0 THEN GOTO 50
70 FOR I=1 TO 12
80 N=RND(10)
90 GOSUB 200
100 BEEP 20,2
110 WAIT 5
120 NEXT
130 FOR I=1 TO 6
140 N=RND(10)
150 GOSUB 200
160 BEEP 20,2
170 WAIT 20
180 NEXT
190 GOTO 50
200 '@PRINTN
210 Z=[N]
220 FOR P=1 TO 6
230 Y=Z%2
240 OUT P,Y
250 Z=Z/2
260 NEXT
270 Y=Z%2
280 LED Y
290 RETURN

※新OUT命令対応版

ファームウェア1.0.2b8から、LEDポートがOUT7ポートとして制御できるようになりました。
対応したルーレットプログラムです。だいぶシンプルになりました。

10 '*7SEG ROULETTE*
20 LET [0],`0111111,`0000110,`1011011,`1001111,`1100110,`1101101,`1111101,`0100111,`1111111,`1101111
30 OUT [0]
40 '@START
50 IF BTN()==0 THEN GOTO 40
60 FOR I=1 TO 10
70 OUT [RND(10)]
80 BEEP 20,2
90 WAIT 6
100 NEXT
110 FOR I=1 TO 5
120 OUT [RND(10)]
130 BEEP 20,2
140 WAIT 12
150 NEXT
160 GOTO 40

越の爺い越の爺い 2015/07/17 13:24 いつも楽しく拝見しています。今回の7セグメントのLEDにLEDの出力を使われていたのは、目からうろこでした! ところで、IchigoJamでは、「バーサライト」は出来るのでしょうか?ふと思いました。電子工作の技術も技量も不足な私では難しく、出来れば挑戦の程 お願いします。勝手なお願いで申し訳ありません。

shiro0922shiro0922 2015/07/17 23:43 コメントありがとうございます。バーサライトはPOVのことですね(LEDを点滅させて、全体を移動させて空中に文字や模様を描く)。私もArduinoでは過去にやったことがあります。
実はIchigoJamでLEDの点滅をいろいろ試しているのですが、あまり速度が出ません。OUT命令があまり速くないようです。POVは工作やプログラムは難しくないのですが、動作の高速性が命なので、IchigoJamでは難しいかもしれません。

越の爺い越の爺い 2015/07/18 10:14 ご返信ありがとうございます。
難しいですか。残念です。IchigoJamの公式ロゴが表示出来ればいいなと思ったものですから。
ありがとうございました。これからも楽しみに拝見させて戴きます。
益々のご活躍をお祈り申しあげます。

スパム対策のためのダミーです。もし見えても何も入力しないでください
ゲスト


画像認証

トラックバック - http://d.hatena.ne.jp/shiro0922/20150716/1436972916
ダウンロード
リンク集
アクセスカウンター