Hatena::ブログ(Diary)

SHIROのモバイル日記 RSSフィード Twitter

2018-06-23

[]人生日数計算

以前に作って、FacebookIchigoJam-FANグループには載せていたプログラムですが、改めてブログに掲載します。
f:id:shiro0922:20180623061710p:image:w360
自分の誕生日を入力すると、現在(プログラム内で指定、4行目)までの日数を計算して表示します。
なお、日数が32767日(約89歳)を越えてマイナスになる場合ですが、無理矢理+65536した値を表示してみました(42〜52行)。
これで0歳〜1839年生まれまでちゃんと計算できます。

プログラムリスト

1 '*Life Days
2 CLV
3 LET [1],31,28,31,30,31,30,31,31,30,31,30,31
4 P=2018:Q=6:R=23
5 '
6 '@BIRTHDAY
7 ?"*Input Your Birthday"
8 ?"Year=";:INPUT Y
9 IF Y>P OR Y<1839 GOTO 6
10 ?"Month=";:INPUT M
11 IF M<1 OR M>12 GOTO 6
12 ?"Day=";:INPUT D
13 IF D<1 GOTO 6
14 IF M!=2 AND D>[M] GOTO 6
15 Z=Y:GSB 55
16 IF M=2 AND D>[2]+C GOTO 6
17 '
18 E=D
19 FOR I=0 TO M-1:E=E+[I]:NEXT
20 Z=Y:GSB 55
21 IF M>2 E=E+C
22 S=R
23 FOR I=0 TO Q-1:S=S+[I]:NEXT
24 Z=P:GSB 55
25 IF Q>2 S=S+C
26 T=S-E
27 IF Y=P IF T>=0 GOTO 38 ELSE GOTO 6
28 T=T+365
29 Z=Y:GSB 55
30 T=T+C
31 IF Y=P-1 GOTO 38
32 '
33 FOR I=Y+1 TO P-1
34 Z=I:GSB 55
35 T=T+365+C
36 NEXT
37 '
38 '@ANSWER
39 ?"*Your Life Days=";
40 IF T>=0 ?T:END
41 '
42 LET [20],6,3,5,5,6
43 C=0
44 FOR I=0 TO 4
45 J=20+I:K=30+I
46 [K]=T%10+[J]-C
47 C=0:IF [K]<0 [K]=[K]+10:C=1
48 T=T/10
49 NEXT
50 FOR I=34 TO 30 STEP -1
51 ?[I];
52 NEXT
53 ?:END
54 '
55 '@LEAP
56 C=(Z%4=0 AND Z!=1900):RTN

IchigoJamは内部に時計が無いので、4行目で現在の日付を設定しています。適宜変更してください。

Web版

こちらをクリック。

スパム対策のためのダミーです。もし見えても何も入力しないでください
ゲスト


画像認証

トラックバック - http://d.hatena.ne.jp/shiro0922/20180623/1529702470
リンク集