Tociyuki::Diary

tociyuki によるPerl・Rubyのコード説明を中心に、日常雑記も混在 : B F twitter GitHub CPAN 本館

2012年02月06日

■[Perl]WalWiki の CSV テーブル行のフォーマット部を書き直し

YukiWiki 2.1.3 のソースの中に WalWiki からバックポートした CSV データをテーブルに組み立てる部分が組み込まれています。カラムの前後にスペースを置いておくと、左右詰め・中央詰めになり、イコールを2つ置いたカラムは直左のカラムを colspan するようにマークアップします。この部分、パズルのようで、私にはぱっと読んで動作を理解することができませんでした。

⇒ yukiwiki213.zip の $BASE/wiki.cgi より

        } elsif (/^\,(.*?)[\x0D\x0A]*$/) {
            &back_push('table', 1, \@saved, \@result, ' border="1"');
            #######
            # This part is taken from Mr. Ohzaki's Perl Memo and Makio Tsukamoto's WalWiki.
            # XXXXX
            my $tmp = "$1,";
            my @value = map {
                /^"(.*)"$/ ? scalar($_ = $1, s/""/"/g, $_) : $_
            } ($tmp =~ /("[^"]*(?:""[^"]*)*"|[^,]*),/g);
            my @align = map {
                (s/^\s+//) ? ((s/\s+$//) ? ' align="center"' : ' align="right"')
                : ''
            } @value;
            my @colspan = map {($_ eq '==') ? 0 : 1} @value;
            for (my $i = 0; $i < @value; $i++) {
                if ($colspan[$i]) {
                    while ($i + $colspan[$i] < @value and $value[$i + $colspan[$i]] eq '==') {
                        $colspan[$i]++;
                    }
                    $colspan[$i] = ($colspan[$i] > 1) ? sprintf(' colspan="%d"', $colspan[$i]) : '';
                    $value[$i] = sprintf('<td%s%s>%s</td>', $align[$i], $colspan[$i], &inline($value[$i]));
                } else {
                    $value[$i] = '';
                }
            }
            push(@result, join('', '<tr>', @value, '</tr>'));
            # XXXXX
            #######

そこで、数行長くなるのですけど、わかりやすさ優先で書き直してみました。

⇒ https://gist.github.com/1751969 (ユニット・テスト)

        } elsif (/^\,(.*?)[\x0D\x0A]*$/) {
            back_push('table', 1, \@saved, \@result, q{ border="1"});
            my $csv = "$1,";
            my @td;
            while ($csv =~ m{
                \G(?:"([^"]*(?:""[^"]*)*)"|([^,]*)), ((?:(?:"=="|==),)*)
            }gmosx) {
                my($data, $span_mark) = (defined $1 ? $1 : $2, $3);
                if ($1) {
                    $data =~ s/""/"/gmosx;
                }
                my $align = q{};
                if ($data =~ m/\A([ ]+)?(.*?)([ ]+)?\z/mosx) {
                    if ($1) {
                        $align = $3 ? q{ align="center"} : q{ align="right"};
                    }
                    $data = $2;
                }
                my $colspan = q{};
                if ($span_mark) {
                    my $n = 1 + ($span_mark =~ tr/,/,/);
                    $colspan = qq{ colspan="$n"};
                }
                push @td, sprintf '<td%s%s>', $align, $colspan;
                push @td, inline($data);
                push @td, '</td>';
            }
            push @result, (join q{}, '<tr>', @td, '</tr>');

1つだけ、オリジナルから仕様を変更しています。CSV の先頭カラムに colspan マークを置いても、colspan マークとはみなさずに、カラムのデータ扱いするようにしました。この辺の挙動は、ユニット・テストに記述してあります。

Permalink | コメント(0) | トラックバック(0) | 21:54

和田先生のユリウス暦とグレゴリオ暦両方対応の「パラメトロン計算機: ユリウス日」計算コードを perl に意訳してみました。通常、ユリウス日は天文計算に使う目的が多く、倍精度浮動小数点演算で求めるものですが、和田先生のコードは整数演算で求めているのがポイントでしょう。オリジナルから変更した箇所は、うるう年かどうかの判定式をユリウス暦とグレゴリオ暦の両方一発で求めるようにしたぐらいです。グレゴリオ暦への切替日より後かどうかの判定には、Perl はリストの比較ができないので、日付をパックしてから文字列比較してみました。

my @YDAY = (
    [-31, 0, 31, 59, 90, 120, 151, 181, 212, 243, 273, 304, 334, 365],
    [-31, 0, 31, 60, 91, 121, 152, 182, 213, 244, 274, 305, 335, 366],
);

sub julian_date {
    my($y, $m, $d) = @_;
    use integer;
    my $leap = $y > 1600 && $y % 100 == 0 ? $y % 400 == 0
              : $y % 4 == 0;
    my $a = ($y + 4712) * 365;
    my $b = ($y + 4712 + 3) / 4;
    my $c = 0;
    if ($y > 1601) {
        my $j = $y - 1601;
        $c = $j / 400 - $j / 100;
    }
    my $e = (pack 'nnn', $y, $m, $d) ge (pack 'nnn', 1582, 10, 15) ? -10 : 0;
    my $f = $YDAY[$leap ? 1 : 0][$m];
    my $g = $d - 1;
    return $a + $b + $c + $e + $f + $g;
}

ついでに、自分が普段使っている天文計算用の倍精度浮動小数点演算を使う C 言語のコードは、グレゴリオ暦の時代だけを計算する方法です。ユリウス暦のずれを補正しないで良いので、短くなります。こっちも Perl に訳してみました。

sub julian_date {
    my($yyyy, $mm, $dd, $hh) = @_;
    my($y, $m) = $mm > 2 ? ($yyyy, $mm) : ($yyyy - 1, $mm + 12);
    my $c = (int $y / 400) - (int $y / 100);
    return (int 365.25 * $y) + (int 30.6001 * ($m + 1)) + $dd + $hh / 24 + 1720996.5 + $c;
}

これをどこで拾ったのか30年以上も前のことなので、はっきり覚えてないのですけど、確か古の FORTRAN の数値計算ライブラリにあったもののような記憶があります。

Permalink | コメント(0) | トラックバック(0) | 21:38

トラックバックについて: 事前連絡・了解は不要です。必ず当方へのリンクまたはURLを含んでください。異論・反論は歓迎、当方への誹謗中傷もご自由に。
コメントについて: 個人情報、アダルト・卑猥な内容、宣伝目的の告知、水谷敏行(tociyuki) を除く第三者への中傷の書き込み、を禁止します。該当するものは削除します。誤り指摘、取り下げ要求は、できれば直接的にガツンと言ってくださるとありがたいです。

Tociyuki::Diary

2012年02月09日

■[Perl]YukiWiki 2.1.3 のグローバル変数参照箇所リスト

グローバル変数

グローバル定数

2012年02月06日

■[Perl]WalWiki の CSV テーブル行のフォーマット部を書き直し

2012年02月04日

■[Perl]ユリウス日