ヤルキデナイズドだった

■[Perl6]Perl 6 でクラスメソッドを書く 00:00

Perl 6 ではインスタンスメソッドとクラスメソッドは区別されません。オブジェクトのアトリビュートをアクセスしていないメソッドはすべてクラスメソッドとして呼ぶことができます。

class C {
    method hello() {
        say 'hello';
    }

    has $!aisatsu = 'konnichiwa';
    method konnichiwa() {
        say $!aisatsu;
    }
}

C.new.hello; # => hello
C.hello; # => hello

C.new.konnichiwa; # => konnichiwa
# C.konnichiwa
# Error: Type objects are abstract and have no attributes, but you tried to access $!aisatsu

メソッドがクラスに対して呼ばれたとき、メソッド内の self 関数はクラスオブジェクトを返します。インスタンスに対して呼ばれたときはインスタンスを返します。クラスオブジェクトは未定義値なので、 self.defined を呼ぶことでメソッドがクラスに対して呼ばれたかどうか知ることができます。

class C {
    method whoami() {
        if self.defined {
            say 'An instance of C';
        }
        else {
            say 'C class';
        }
    }
}

C.whoami; # => C class
C.new.whoami; # => An instance of C

マルチディスパッチを使えば場合分けをスマートに書けます：

class C {
    multi method whoami($self where :defined :) {
        say 'An instance of C';
    }

    multi method whoami() {
        say 'C class';
    }
}

C.whoami; # => C class
C.new.whoami; # => An instance of C